#!/bin/tcsh

source ${HOME}/.aliases
setenv HERE "`pwd`"
setenv KDEMODULE "`basename ${HERE}`"
setenv DIFF "/opt/fsw4sun/bin/diff -w -u"

if ( -f "${HERE}/DIFFCREATED" ) then
	echo "You already DID THAT."
	echo "Remove ${HERE}/DIFFCREATED to run this again."
	exit 1
endif

echo "Creating diff package for ${KDEMODULE}."

find . -type f -name "*.kde.orig" -print > DIFF.KDE.ORIG
sed -e 's#.kde.orig##g' DIFF.KDE.ORIG > FilesToDiff

foreach i ( `cat ./FilesToDiff` )
	echo "Diffing $i ... "
	${DIFF} "${i}.kde.orig" "${i}" > "${i}.diff"
end

find . -type f -name "*.diff" -print > ${HERE}/DiffList

if ( -f "${KDEMODULE}.diff.tar.bz2" ) then
	echo "Removing Old Diff Package ${KDEMODULE}.diff.tar.bz2."
	rm -f "${KDEMODULE}.diff.tar.bz2"
endif

tar cvf "${KDEMODULE}.diff.tar" -I ./DiffList
bzip2 --best "${KDEMODULE}.diff.tar"
chmod 0755 "${KDEMODULE}.diff.tar.bz2"
md5 "${KDEMODULE}.diff.tar.bz2" > "${KDEMODULE}.diff.md5"
chmod 0755 "${KDEMODULE}.diff.md5"

cat /dev/null > "${HERE}/DIFFCREATED"
unsetenv KDEMODULE
echo "Done."

